PLANEXすべて クチコミ掲示板

n日前の記録ファイルの自動削除バッチファイル

[ボズシ]

下記URL　BootTimerなどのフリーソフトに登録し毎日走らせます。
http://www.forest.impress.co.jp/library/software/boottimer/
以下バッチファイルのソースコードです。11日前の録画ファイルを自動削除します。
===================
@echo off
rem −−−−−−−−−−−−−−−
rem 基本プログラムの拝借先:http://win-cmd.seesaa.net/article/83689257.html
rem 今日からn日前の保存画像を消去する
rem n（数値）
rem date・・YYYY/MM/DD 形式
rem RecDrv : 保存ドライブの指定
rem Cam1path : カメラ1の保存パス
rem CamNpath : カメラNの保存パス
rem −−−−−−−−−−−−−−−

set n=11
set RecDrv=S:
set Cam1path=Lan_Cam\Data\Record\Camera 1
set Cam2path=Lan_Cam\Data\Record\Camera 2
set Cam3path=Lan_Cam\Data\Record\Camera 3
set Cam4path=Lan_Cam\Data\Record\Camera 4

rem ===年月日の分割===
set yy=%date:~0,4%
set mm=%date:~5,2%
set dd=%date:~8,2%
set count=0

:Repeat

rem ===月日の数値化（8進数対策）===
set /a mm=1%mm%-100
set /a dd=1%dd%-100

set /a dd=%dd%-1

if %dd% NEQ 0 goto end

rem ===月跨り処理===
set /a mm=%mm%-1
if %mm% equ 0 set mm=12&&set /a yy=%yy%-1

set /a dd=%dd%+31
if "%mm%"=="2" set /a dd=%dd%-3
if "%mm%"=="4" set /a dd=%dd%-1
if "%mm%"=="6" set /a dd=%dd%-1
if "%mm%"=="9" set /a dd=%dd%-1
if "%mm%"=="11" set /a dd=%dd%-1

rem ===閏年処理4で割り切れるか？===
set /a u=%yy% %% 4
if not %u%==0 goto end
rem ===100で割り切れて、400で割り切れないか？===
set /a u=%yy% %% 400
set /a v=%yy% %% 100
if %v%==0 if not %u%==0 goto end
rem ===2月か？===
if %mm% equ 2 set /a dd=%dd%+1

:end
set mm=0%mm%
set mm=%mm:~-2%

set dd=0%dd%
set dd=%dd:~-2%
set /a count=%count%+1
set DT=%yy%-%mm%-%dd%

if %count% neq %n% goto Repeat

rem ===ここよりファイル削除の実行===
%RecDrv%
cd %Cam1path%
del Schedule_%DT%_????????.avi
del Schedule_%DT%_????????.mp4
del mp4ConvLog_%DT%.txt

cd \
cd %Cam2path%
del Schedule_%DT%_????????.avi
del Schedule_%DT%_????????.mp4
del mp4ConvLog_%DT%.txt

cd \
cd %Cam3path%
del Schedule_%DT%_????????.avi
del Schedule_%DT%_????????.mp4
del mp4ConvLog_%DT%.txt

cd \
cd %Cam4path%
del Schedule_%DT%_????????.avi
del Schedule_%DT%_????????.mp4
del mp4ConvLog_%DT%.txt

echo "消去しました"
ping localhost -n 3　> nul
exit

書込番号：19876583

[Mild7-1Soft]

質問です。
バッチファイルによる記録ファイルの自動圧縮やn日前の記録ファイルの自動削除バッチファイル　を走らせるＰＣは
どのようにしておりますか？
常時稼働のＰＣでしょうか？　もし、良かったら教えて下さいませ。

書込番号：19877939

[ボズシ]

Windows7 自作のフルタワーPCです。
地デジ録画サーバー　兼　FAXサーバー 兼　NASのバックアップ3rdファイルサーバー　兼　防犯カメラサーバー　兼　ラベルプリンターサーバー　として24時間稼働させてます。
BootTimerにて毎日am4:00にリブートさせメモリーリークを回避してます。

マザー：GA-Z77-D3H
CPU：core i7-3770
HDDシステム：2.5inch 500MB
HDDデーター：3.5inch 3TB；地デジ録画に1TB，NASのバックアップに2TBの2パーテション
地デジ板：3枚6チューナー
その他：モデム1枚
コンソールはディスプレイ，キーボード，マウス一切無し。(非常事態の時には繋ぎますが)
操作はRealVNCでリモート管理です。
ごく普通のちょっとだけハイパワーなのっぺりマシンです。

防犯カメラの画像は2TBのNASに一時記録しもう1台のNASに1日遅れで自動バックアップ，それをこのPCに2日遅れでバックアップしてます。

書込番号：19878470

[Mild7-1Soft]

>Windows7 自作のフルタワーPCです。
ありがとうございます。

書込番号：19878545

[あっ熊が来たりて鰾を拭く]

n日前の日付を求めるのに苦労しているようですね。
バッチファイルだけで求めてしまうので脱帽です。(^^)/

文字列から数値に変換するとろや、また文字列に戻す
ところ("0"の脱着)のテクニックがとても参考になります。

書込番号：19878961

[ボズシ]

あっ熊が来たりて鰾を拭くさん，お褒めのお言葉有り難うございます。

n日前の日付の抽出部分は他人のブログから拝借したもので歴代2〜3名の方が関わっている様です。
私はファイル名にはめ込んだだけです。

録画データーはあっという間にディスク容量を使い果たしますのでファイルサイズを圧縮したり古いファイルを消去したりする作業は自動化しないとやってられません。

作ったバッチを独り占めしていては，と思い公開しました。

書込番号：19879409

バッチファイルによる記録ファイルの自動圧縮

[ボズシ]

防犯カメラとしてNASに録画データーを残す場合のファイルサイズの圧縮を自動で出来る様にバッチファイルを作成しました。
下記URLよりフリーのffmpegをダウンロードしこれを使います。
https://ffmpeg.zeranoe.com/builds/
尚CPUのリソースを大量消費し発熱しブザー鳴りますので「 -threads 2」とし2コアで走らせます。2コアの場合は「-threads 1」
カメラの数は4台，格納パスはS:\Lan_Cam\Data\Record\Camera x，実行ファイル格納庫はC:\Program Files\ffmpeg
以下バッチのソース

rem ==== 変数セット ====
set RecDrv=S:\
set Cam1path=Lan_Cam\Data\Record\Camera 1
set Cam2path=Lan_Cam\Data\Record\Camera 2
set Cam3path=Lan_Cam\Data\Record\Camera 3
set Cam4path=Lan_Cam\Data\Record\Camera 4
set ffmpeg_logpath=mp4ConvLog_%date:~0,4%-%date:~5,2%-%date:~8,2%.txt
rem ==== タイトル表示 ====
title ".avi→.mp4自動変換AutoMp4Conv.bat"
rem =====ここよりCam1の変換実行=====
pushd %RecDrv%..
cd %Cam1path%
call :Conv_ffmpeg
rem =====ここよりCam2の変換実行=====
pushd %RecDrv%..
cd %Cam2path%
call :Conv_ffmpeg
rem =====ここよりCam3の変換実行=====
pushd %RecDrv%..
cd %Cam3path%
call :Conv_ffmpeg
rem =====ここよりCam4の変換実行=====
pushd %RecDrv%..
cd %Cam4path%
call :Conv_ffmpeg
rem ===== end ====
cls
echo "変換終了"
exit
rem ==== 拡張子.aviファイルを抜き出しConv_ffmpeg_Subに引数として渡す =====
:Conv_ffmpeg
echo [%date% %time%] −−変換開始−− >> %ffmpeg_logpath%
for %%i in ("Schedule_"*.avi) do (
call :Conv_ffmpeg_Sub %%i
)
echo [%date% %time%] −−変換終了−− >> %ffmpeg_logpath%
exit /b
rem ==== avi形式を264mp4に変換し生成に成功したら元のaviファイルを消去 ====
:Conv_ffmpeg_Sub
echo Y | "C:\Program Files\ffmpeg\ffmpeg" -i %1 -threads 2 -r 3 -pix_fmt yuv420p -vcodec libx264 "%~n1.mp4"
cls
dir /b "%~n1.mp4"
if %errorlevel%==0 (
del "%1"
echo [%date% %time%] %1 to %~n1.mp4 >> %ffmpeg_logpath%
) else (
echo [%date% %time%] %1 >> %ffmpeg_logpath%
)
exit /b

書込番号：19875255

Windows専用アプリケーション『スマカメPro』

[かもめん]

https://www.planex.co.jp/products/smacame-pro/
22,800円（税抜）
どなたか購入された方おられますか？

運用コストがイマイチわかりづらいですよね。
仮に3台運用だとして、初期費用が22800円として、
運用コスト（365日）がダイレクトモード0円で、ビジネスモードが67000円で、ビジネスモードではカメラの視聴制限がかかるのですが「有料オプションサービスのビジネスモード視聴制限解除」とあり「ビジネスモード視聴制限解除」とは何をさすのか？67000円のことをさすのか？それとも67000円以外にここには記載されていない有料オプションを別途支払う必要があるのか？
ちょっとわかりづらいですね

まあ、でもよくわからなくても、とりあえず購入するつもりです（笑）。

書込番号：19827349

[tanetty]

かもめんさん

推測ですが...。こういうことかと思われます。

▼私の推測(通信方法)

PCはまず�@を試す。ダメな場合のみ�Aで通信する。

�@ダイレクトモード = 直接通信 = サーバ「非」経由 = P2P
→PCは、カメラと直接通信する。

�Aビジネスモード = 間接通信 = サーバ経由 = Relay
→PCは、中継サーバを経由してカメラと間接的に通信する。

▼私の推測(理由)

�@はユーザから見ると、(�Aに比べ)可用性・通信速度ともに高い(中継サーバが動作に無関係だから)。

�@はプ社から見ると、中継サーバの設置・管理をしなくてよい。

�Aはユーザから見ると、ネットワーク条件によらず、接続できる可能性が高まる。

�Aはプ社から見ると、中継サーバの設置・管理というデメリットしかない。なので、ユーザから、中継サーバ利用料として、月額でお金をもらう。

▼推測した理由

(a)Windows用試用版『スマカメ』でカメラに接続したとき、私の環境では、映像の右下に「P2P」と表示されました。
→これはおそらく、「ダイレクトモード」での接続が成功しているものと思われます。
→「ビジネスモード」の際は、「Relay」と表示されるものと思われます((c)参照)。

(b)プ社サイトに、こう書いてあります。
→「多段ルーターなどネットワーク環境により、ビジネスモードで接続されることがあります」

(c)Windows用試用版『スマカメ』をダウンロードする直前の画面で、こう表示されます。
→○Version 1.0.0.2 から Version 1.0.0.3 への変更点
■変更点
Relayモード接続の場合は、90秒で切断する処理を追加しました。

書込番号：19827721

[tanetty]

補足します。

2015年5月に、CS-QR20にWindows用『スマカメ』試用版(1.0.0.0)からの通信経路について調べたことがあります。

その際に私なりに出した結論は、「直接通信してるっぽい」でした。

<<端末はカメラと直接通信しているようです(サーバを経由しない)。>>
http://bbs.kakaku.com/bbs/K0000761546/SortID=18801179/#tab

ですが、その後、CS-QR20側のファームウェアも、Windows用『スマカメ』試用版も、バージョンアップを何度か重ねています。これにより、中継サーバ経由「でも」通信できる機能を実装したのかなぁ...と推測しています。

ただ、少なくとも、次のような企業では、それでもなお、接続できないのではないか、と思われます。

�@カメラ側のネットワークとして、プロクシ経由以外のインターネット抜けを、ファイアウォールでブロックしている。

�APC側のネットワークとして、プロクシ経由以外のインターネット抜けを、ファイアウォールでブロックしている。

そう考える理由は、以下のとおりです。

�@については、カメラ側の設定項目として、プロクシがないため、そう考えます。

�Aについては、少なくともWindows用『スマカメ』試用版の設定項目に、プロクシがないため、そう考えます。

書込番号：19827768

[tanetty]

...とまあ、ゴチャゴチャと長く書きましたが、いちばん言いたいのは、

「想定している環境において、Windows用『スマカメ』試用版(1.0.0.3)からCS-QR20に接続できない場合、そのPCに『スマカメPro』正式版を入れても、CS-QR20におそらく接続できない。だから、事前に必ず試用版で試したほうがいいですよ」

ということです。

長々と失礼いたしました。 m(_ _)m

書込番号：19827778

[tanetty]

訂正。

>>(a)Windows用試用版『スマカメ』でカメラに接続したとき、私の環境では、映像の右下に「P2P」と表示されました。

「右下」ではなく、正しくは「左下」でした。

書込番号：19827834

[スーパカー消しゴム]

一番お安いのを買いましたよ。

３台運用であれば、基本の一番のパッケージだけの購入でOKです。基本パッケージで６台のスマカメまで収容可能です。

かもめんさんの場合は３台とのことなので、関係するのはビジネスモードの67,000円です。これが必要かどうかはP2Pモードで動作できれば不要。リレーモードになるなら購入が必要ということのようです。

私のカメラはすべてP2Pモードで動作しているので22,800円の基本パッケージのみでOKです。

書込番号：19828555

[かもめん]

＞スーパカー消しゴムさん
＞tanettyさん
すぐレスできずすみません、アドバイスに感謝いたします

書込番号：19836454

CyberGate終了につき NO-IPへの変更

[スーパカー消しゴム]

価格.comの掲示板で、CyberGateが7月末でサービス終了との情報を得たので、まだ時間的な猶予はありますが、ひとあし先にNO-IPという別のDDNSサービスに切り替えてみました。

http://www.noip.com/

英語サイトですが、DDNSの基本的な知識があればそう難しいものでもないと思います。　カメラのFWの中でCyberGateからNO IPに切り替えて、必要な情報を設定して無事に動作することを確認しました。

書込番号：19821273

[スーパカー消しゴム]

追加情報

このカメラでDyndnsも選択できたので、７日間無料トライアルを申し込んで使ってみました。当然といえば当然ですが、問題なく動作しました

７日間のトライアルのあとは４０ドル（年額）になるので、個人で利用するならNO-IPで無料で使い続けるのが良さそうですね。

http://dyn.com/

書込番号：19821321

不明なデバイス

[wanwan-mama]

皆さんのコメント見てビックリしました。
昨日より突然繋がらなくなり、思いつく事を全て試しましたが
今日も繋がらず途方に暮れていました。

プラネックスの問題と分かって、なんか納得・・・。
この状態は非常に困ります。
早く解決してもらいたいものです。

書込番号：19747998

iOS9.3でもアプリ『スマカメ』は正常動作します。

[tanetty]

iOS9.3でもアプリ『スマカメ』は正常動作します。
下記環境にて下記内容を確認しました。ご参考までに。

▼環境
・iPod touch 第6世代 iOS9.3
・アプリ『スマカメ』 1.3.1
・CS-QR20のファームウェア 1.25.0.0

▼確認した内容
・インターネット越しに現在映像が見れること。
・インターネット越しに録画映像が見れること。

書込番号：19724740

[sister_sister]

tanetty さんへ

いつも詳しい報告ありがとうございます、tanetty 捜査官！（笑）

書込番号：19726355

[tanetty]

＞sister_sisterさん

ありがとうございます！！
捜査、ガンバリマス！！(笑)

書込番号：19727436