『「mAgicTVマネージャー」のフリーズ検出バッチファイル作成』のクチコミ掲示板

2012年10月下旬 発売

GV-MVP/XS3W

最大15倍録画が可能なWindows8対応の3波チューナー

GV-MVP/XS3W 製品画像

拡大

ショップが販売価格を掲載するまでお待ちください 価格推移グラフ

お気に入り製品に登録すると、価格が掲載された時にメールやMyページでお知らせいたします


価格帯:¥―〜¥― (―店舗) メーカー希望小売価格(税別):¥18,900

TVチューナー:地デジ/BS/CS タイプ:内蔵 インターフェイス:PCI-Exp GV-MVP/XS3Wのスペック・仕様

ネットで買うなら!クレジットカード比較
この製品をキープ

ご利用の前にお読みください

  • GV-MVP/XS3Wの価格比較
  • GV-MVP/XS3Wの店頭購入
  • GV-MVP/XS3Wのスペック・仕様
  • GV-MVP/XS3Wのレビュー
  • GV-MVP/XS3Wのクチコミ
  • GV-MVP/XS3Wの画像・動画
  • GV-MVP/XS3Wのピックアップリスト
  • GV-MVP/XS3Wのオークション

GV-MVP/XS3WIODATA

最安価格(税込):ショップが販売価格を掲載するまでお待ちください 発売日:2012年10月下旬

  • GV-MVP/XS3Wの価格比較
  • GV-MVP/XS3Wの店頭購入
  • GV-MVP/XS3Wのスペック・仕様
  • GV-MVP/XS3Wのレビュー
  • GV-MVP/XS3Wのクチコミ
  • GV-MVP/XS3Wの画像・動画
  • GV-MVP/XS3Wのピックアップリスト
  • GV-MVP/XS3Wのオークション

『「mAgicTVマネージャー」のフリーズ検出バッチファイル作成』 のクチコミ掲示板

RSS


「GV-MVP/XS3W」のクチコミ掲示板に
GV-MVP/XS3Wを新規書き込みGV-MVP/XS3Wをヘルプ付 新規書き込み



ナイスクチコミ3

返信7

お気に入りに追加

標準

PC用テレビチューナー > IODATA > GV-MVP/XS3W

スレ主 ボズシさん
クチコミ投稿数:276件

にょっきり〜さんのLiveモード移行失敗対策バッチ(下記URL)のアップグレード版を作成しました。
http://bbs.kakaku.com/bbs/K0000258773/Page=4/SortRule=1/ResView=all/#15170625

録画ミスにお困りの方でバッチ経験者にご利用いただけると幸いです。

バッチファイルの記述は17年ぶりなので教科書片手の記述です。
変なところを発見された方はツッコミの程宜しくデス。

にょっきり〜さんのbat導入後7ヶ月が経過しましたが,Liveモード移行失敗の自動リカバーを2回ほど経験しました。
しかし別の現象での未録画というケースが多数回発生し,その現象のトレースを行ってきました。
起きている現象の全てでは無いと思いますがtasklistコマンドで「mAgicTVマネージャー」のフリーズを検出することが可能であり,taskkillコマンドとstartコマンドの組合せで「mAgicTVマネージャー」の再起動が可能な場合があることを突き止めました。
「mAgicTVマネージャー」の再起動が不可である場合もありそうなので,再起動に失敗した場合にはOSの再起動を行う様にしてあります。
データーベースエラーが起き「mAgicTVマネージャー」が必ずハングする様なケースではOSの再起動無限ループとなってしまいますので御利用は自己責任で御願い致します。

尚,OSの再起動を毎日am2:55,\iodbadのディレクトリー自動消去を毎日am2:59,番組データー更新を毎日am3:10,当バッチファイルの起動を毎日am3:00に行っております。
録画する番組は週に120番組前後,チューナーは3枚同録6番組というハードな使用状況です。


*****以下記述

@echo off
setlocal
set mlogpath=

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"

:jobloop
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt
find /i "Liveモード移行に失敗" %mlogpath%
if %errorlevel%==0 goto mtvtaskfail
echo [%date% %time%] mtvLog点検:正常稼働中
ping localhost -n 30 > nul

tasklist /v /fo "Table" /nh /fi "IMAGENAME eq mtvManager.exe" | find /i "Not Responding"
if %errorlevel%==0 goto mtvtaskfail
echo [%date% %time%] mtvManagerタスク:正常稼働中
ping localhost -n 30 > nul
goto jobloop

:mtvtaskfail
echo 異常を検出しました
echo [%date% %time%]異常検出 >> %mlogpath%
tasklist /v /fi "IMAGENAME eq mtvManager.exe" >> %mlogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%mtvtaskfail.txt"
type nul > %mlogpath%
echo mtvManager強制終了中
taskkill /f /im mtvUpdate.exe
taskkill /f /im mtvManager.exe
ping localhost -n 30 > nul

echo [%date% %time%] mtvManagerTV再起動中
start /wait /d "%ProgramFiles(x86)%\I-O DATA\mAgicTVGT" /b mtvManager.exe
ping localhost -n 30 > nul

tasklist /v /fo "Table" /nh /fi "IMAGENAME eq mtvManager.exe" | find /i "Not Responding"
if %errorlevel%==0 goto livefail
echo [%date% %time%] mtvManager再起動成功
goto jobloop

:livefail
echo [%date% %time%] mtvManager再起動失敗
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%shutdown.txt"
type nul > %mlogpath%
echo [%date% %time%] 10秒後にWindowsを強制再起動します
ping localhost -n 10 > nul
shutdown -r
exit

*****以上


***** \iodbadのディレクトリー自動消去bat 以下記述

setlocal
rem cd %APPDATA%"\I-O DATA\mAgicTV"
RD /s /q %APPDATA%"\I-O DATA\mAgicTV\iodbad

*****以上

書込番号:16098227

ナイスクチコミ!1


返信する
スレ主 ボズシさん
クチコミ投稿数:276件

2013/07/03 00:27(1年以上前)

更新しました。

【変更内容】
ログファイルをはき出す様にした
タスク再起動の無限ループに陥る場合がある為for nextで2回までのループとした
mtvManagerが常駐していないエラーに対応
mtvManagerが1回の巡回では非応答となる可能性があるので2回巡回
DelIodbad.batから当バッチを強制終了させる為タイトル表示を追加
mtvGuideが起動したまま固まる場合があるので検出処理ルーチン追加

【使用方法】
深夜2:59 DelIodbad.bat 実効
再起動後に mAgicTV_Ver6.bat を2〜3分遅延起動させる
mtvManagerはログオン時に自動起動
深夜3:30番組表更新

【その他】
録画専用機としているマシンを想定
コマンドプロンプト及びバッチを理解されている方向け
Windows7 64bit/Windows8 64bit対象,32bit環境は適切なパスに書き替えてください

【未解決問題】
フリーズしているのにRunningと応答する場合(録画放棄状態でログもはき出さない)がある。
深夜0時を境に起きる確率が高い。
この時mtvGuideを起動させるとmtvGuide画面が出ないがmtvGuideもmtvManagerもRunningなので検出できない。

***** DelIodbad.bat 以下記述 *****
@echo off
setlocal
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
set batver=ver211

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
echo %date% %time%taskkill実行しましすbyDelliodbad_bat%batver% >> %tllogpath%

rem ========= ウォッチドッグbat強制終了 =========
taskkill /f /fi "windowtitle eq 管理者: mTgicTVmanagerウォッチドッグbat" >> %tllogpath%
ping localhost -n 62 > nul

rem ========= mtvUpdate.exe強制終了 =========
taskkill /f /im mtvUpdate.exe >> %tllogpath%

rem ========= mtvGuide.exe強制終了 =========
taskkill /f /im mtvGuide.exe >> %tllogpath%
ping localhost -n 3 > nul

rem ========= mtvManager.exe強制終了 =========
taskkill /f /im mtvManager.exe
ping localhost -n 105 > nul

rem ========= iodbadフォルダー消去 =========
cd %APPDATA%"\I-O DATA\mAgicTV"
RD /s /q %APPDATA%"\I-O DATA\mAgicTV\iodbad
cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
echo %date% %time%iodbad_folder消去しましたbyDelliodbad_bat%batver% >> %tllogpath%
ping localhost -n 2 > nul

rem ========= Windows再起動 =========
echo %date% %time%Windowsを再起動しますbyDelliodbad_bat%batver% >> %tllogpath%
shutdown -r

***** 以上 *****

書込番号:16322518

ナイスクチコミ!1


スレ主 ボズシさん
クチコミ投稿数:276件

2013/07/03 00:29(1年以上前)

文字数制限に引っかかりましたのでここにmAgicTV.bat投稿します

***** mAgicTV.bat 以下記述 *****
@echo off
setlocal
set mlogpath=
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
set batver=Ver601
title mTgicTVmanagerウォッチドッグbat

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt

echo %date% %time%mAgicTV_%batver%バッチ起動しました >> %tllogpath%
echo [%date% %time%] mAgicTV_%batver%バッチ稼働開始−5分後に巡回を始めます
ping localhost -n 300 > nul

:jobouterloop
for /l %%a in (1,1,2) do (
call :jobloop
)
goto osreboot

:jobloop
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
find /i "Liveモード移行に失敗" %mlogpath% > nul
if %errorlevel%==0 goto livefail
echo [%date% %time%] mtvLogLive点検:正常稼働中
ping localhost -n 29 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvtaskfail
:mtvtasksafe
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Running" > nul
if %errorlevel%==1 goto mtvtasknotrun
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvGuidefail
echo [%date% %time%] mtvManagerタスク:正常稼働中
:mtvGuidesafe
ping localhost -n 29 > nul

goto jobloop

:mtvGuidefail
ping localhost -n 20 > nul
tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto osreboot
echo mtvGuideが起動したまま固まっています
echo %date% %time%mtvGuidefailのフリーズ検出by_mAgicTV_%batver% >> %tllogpath%
goto mtvGuidesafe

:mtvtasknotrun
echo mtvtaskが走っていません
echo %date% %time%mtvtask走っていませんby_mAgicTV_%batver% >> %tllogpath%
start /wait /d "%ProgramFiles(x86)%\I-O DATA\mAgicTVGT" /b mtvManager.exe
ping localhost -n 120 > nul
goto jobloop

:livefail
echo live異常を検出しました
echo %date% %time%live異常検出by_mAgicTV_%batver% >> %tllogpath%
goto failconfluence

:mtvtaskfail
ping localhost -n 10 > nul
tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==1 goto mtvtasksafe
echo mtvtask異常を検出しました
echo %date% %time%mtvtask異常検出_by_mAgicTV_%batver% >> %tllogpath%
goto failconfluence

:failconfluence
tasklist /v /fi "imagename eq mtvManager.exe" >> %tllogpath%
type nul >> %tllogpath%
echo mtvManager強制終了中
taskkill /f /im mtvUpdate.exe
taskkill /f /im mtvManager.exe
ping localhost -n 60 > nul

echo [%date% %time%] mtvManager再起動中
echo %date% %time%mtvManager再起動試行 >> %tllogpath%
start /wait /d "%ProgramFiles(x86)%\I-O DATA\mAgicTVGT" /b mtvManager.exe
ping localhost -n 60 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto osreboot
echo [%date% %time%] mtvManager再起動成功しました
echo %date% %time%mtvManager再起動成功_by_mAgicTV_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%mtvtaskfail.txt" > nul
type nul > %mlogpath%
goto :EOF

:osreboot
echo [%date% %time%] mtvManager再起動失敗しました
echo %date% %time%mtvManager再起動失敗 >> %tllogpath%
echo [%date% %time%] 10秒後にWindowsを強制再起動します
ping localhost -n 10 > nul
echo %date% %time%Windows再起動_by_mAgicTV_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%shutdown.txt" > nul
type nul > %mlogpath%
shutdown -r
exit
goto :EOF

***** 以上 *****


書込番号:16322528

ナイスクチコミ!1


スレ主 ボズシさん
クチコミ投稿数:276件

2013/08/08 22:35(1年以上前)

最新版のスパゲッティーバッチファイル
Ver602 mtvGuide2nd点検タイマー20→30secに変更
Ver603 mtvtaskfailの再検出を10秒後→30秒後(赤面バグも修正)
Ver604 起動遅延5分→8分
Ver605 DiXiMMediaServerサービスのフリーズ検出追加

***** mAgicTV.bat 以下記述 *****

setlocal
set mlogpath=
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
set batver=Ver605
title mTgicTVmanagerウォッチドッグbat

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt

echo %date% %time%mAgicTV_%batver%バッチ起動しましたby_mAgicTV_%batver% >> %tllogpath%
echo [%date% %time%] mAgicTV_%batver%バッチ稼働開始−8分後に巡回を始めます
ping localhost -n 480 > nul

:jobouterloop
for /l %%a in (1,1,2) do (
call :jobloop
)
goto osreboot

:jobloop
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
find /i "Liveモード移行に失敗" %mlogpath% > nul
if %errorlevel%==0 goto livefail
echo [%date% %time%] mtvLogLive点検:正常稼働中
ping localhost -n 29 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvtaskfail
:mtvtasksafe
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Running" > nul
if %errorlevel%==1 goto mtvtasknotrun
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvGuidefail
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq dms_sync_svc.exe" | find /i "0:00:00" > nul
if %errorlevel%==0 goto dms_sync_svcfail

echo [%date% %time%] mtvManagerタスク:正常稼働中
:mtvGuidesafe
ping localhost -n 28 > nul
goto jobloop

:dms_sync_svcfail
echo DiXiMMediaServerサービスが固まっています
echo %date% %time%DiXiMMediaServerサービスフリーズ検出by_mAgicTV_%batver% >> %tllogpath%
goto osreboot

:mtvGuidefail
ping localhost -n 30 > nul
echo mtvGuideが応答していません
echo %date% %time%mtvGuideが応答していませんby_mAgicTV_%batver% >> %tllogpath%
tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto osreboot
goto mtvGuidesafe

:mtvtasknotrun
echo mtvtaskが走っていません
echo %date% %time%mtvtask走っていませんby_mAgicTV_%batver% >> %tllogpath%
start /wait /d "%ProgramFiles(x86)%\I-O DATA\mAgicTVGT" /b mtvManager.exe
ping localhost -n 120 > nul
goto jobloop

:livefail
echo live異常を検出しました
echo %date% %time%live異常検出by_mAgicTV_%batver% >> %tllogpath%
goto failconfluence

:mtvtaskfail
ping localhost -n 30 > nul
tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==1 goto mtvtasksafe
echo mtvtask異常を検出しました
echo %date% %time%mtvtask異常検出_by_mAgicTV_%batver% >> %tllogpath%
goto failconfluence

:failconfluence
tasklist /v /fi "imagename eq mtvManager.exe" >> %tllogpath%
type nul >> %tllogpath%
echo mtvManager強制終了中
taskkill /f /im mtvUpdate.exe
taskkill /f /im mtvManager.exe
ping localhost -n 60 > nul

echo [%date% %time%] mtvManager再起動中
echo %date% %time%mtvManager再起動試行by_mAgicTV_%batver% >> %tllogpath%
start /wait /d "%ProgramFiles(x86)%\I-O DATA\mAgicTVGT" /b mtvManager.exe
ping localhost -n 60 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq mtvManager.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto osreboot
echo [%date% %time%] mtvManager再起動成功しました
echo %date% %time%mtvManager再起動成功_by_mAgicTV_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%mtvtaskfail.txt" > nul
type nul > %mlogpath%
goto :EOF

:osreboot
echo [%date% %time%] 再起動失敗
echo %date% %time%再起動失敗by_mAgicTV_%batver% >> %tllogpath%
echo [%date% %time%] 10秒後にWindowsを強制再起動します
echo %date% %time% 10秒後Windows強制再起動by_mAgicTV_%batver% >> %tllogpath%
ping localhost -n 10 > nul
echo %date% %time%Windows再起動_by_mAgicTV_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%shutdown.txt" > nul
type nul > %mlogpath%
shutdown -r
exit
goto :EOF

書込番号:16450630

ナイスクチコミ!0


スレ主 ボズシさん
クチコミ投稿数:276件

2016/05/14 19:52(1年以上前)

バッチは現在Ver6.31です。
対象OSはWin7たぶん8.1でもOK,Win10は未確認
対象のサポートライブラリーVer6.13
どのバージョンからかは不明ですがmAgicTV GTマネージャーにタスク管理が追加されていて以下の様なログが吐き出される様になっています。
==================================
2016/05/13 04:16:58 [プロセス管理] mAgicマネージャ GT は応答を停止しました。
2016/05/13 04:16:58 [プロセス管理] mAgicマネージャ GT の再起動を試行しました。(0)
2016/05/13 04:17:05 [プロセス管理] mAgicマネージャ GT が正常に開始されました。
==================================
したがってバッチファイル内でプロセス管理をやると競合しますのでログファイルの点検に変更しました。
不具合発生時にフリーソフト「メモリーの掃除屋さん」を使うと効果があるケースが確認できました。
下記URLより落としてバッチファイルの格納ディレクトリーにMemClCmd.exeをコピーしてください。
http://www.vector.co.jp/soft/win95/hardware/se190988.html
Liveモード移行失敗は録画ファイルの保存先HDDをデフラグすると発症を抑えられます。
ただOSのデフラッグではダメで下記URLのデフラグソフト(フリー版)を使ってます。
http://www.piriform.com/defraggler
設定→スケジュール→対象ドライブを選択しタスクが空いている時間帯にデフラグ形式をフルに設定します。
以下バッチファイルのソース
==================================
@echo off
setlocal
set mlogpath=
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
set batver=Ver631
title mTgicTVmanagerウォッチドッグbat

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt

echo %date% %time% mAgicTV_バッチ起動しました_by_mAgicTV(mainjob)_%batver% >> %tllogpath%
echo [%date% %time%] mAgicTV_%batver%バッチ稼働開始−1分後に巡回を始めます
ping localhost -n 60 > nul
echo %date% %time% メインループを始動_by_mAgicTV(mainjob)_%batver% >> %tllogpath%

:jobloop
set mlogpath=mtvLog%date:~0,4%%date:~5,2%%date:~8,2%.txt
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
echo [%date% %time%] mlogpathは%mlogpath%
echo [%date% %time%] tllogpathは%tllogpath%

find /i "Live モード移行に失敗。" %mlogpath% > nul
if %errorlevel%==0 goto livefail
echo [%date% %time%] mtvLogLive点検:正常稼働中
ping localhost -n 30 > nul

find /i "mAgicマネージャ GT は応答を停止しました。" %mlogpath% > nul
if %errorlevel%==0 goto mtvtaskerr
:test2_rtn

find /i "mAgicマネージャ GT を終了出来ませんでした。" %mlogpath% > nul
if %errorlevel%==0 goto mtvtaskfail

tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvGuidefail
ping localhost -n 1 > nul

tasklist /v /fo "Table" /nh /fi "imagename eq dms_sync_svc.exe" | find /i "0:00:00" > nul
if %errorlevel%==0 goto dms_sync_svcfail

echo [%date% %time%] mtvManagerタスク:正常稼働中
:mtvGuidesafe
ping localhost -n 28 > nul
goto jobloop

書込番号:19875105

ナイスクチコミ!0


スレ主 ボズシさん
クチコミ投稿数:276件

2016/05/14 19:54(1年以上前)

rem sub_1######
:dms_sync_svcfail
echo [%date% %time%] DiXiMMediaServerサービスが固まっています
echo %date% %time% DiXiMMediaServerサービスフリーズ検出_by_mAgicTV(dms_sync_svcfail)_%batver% >> %tllogpath%
tasklist /v /fo "Table" /nh /fi "imagename eq dms_sync_svc.exe" | find /i "0:00:00" > nul
if %errorlevel%==0 goto dms_sync_NotResponse
echo [%date% %time%] DiXiMMediaServerサービス確認
echo %date% %time% DiXiMMediaServerサービス確認_by_mAgicTV(dms_sync_svcfail)_%batver% >> %tllogpath%
goto jobloop
:dms_sync_NotResponse
echo [%date% %time%] やはりDiXiMMediaServerサービスが固まっています
echo %date% %time% 再度DiXiMMediaServerサービスフリーズ検出_by_mAgicTV(dms_sync_svcfail)_%batver% >> %tllogpath%
echo [%date% %time%] 手動でサービスの再起動を行ってください
echo %date% %time% キー待ち_by_mAgicTV(dms_sync_svcfail)_%batver% >> %tllogpath%
pause
echo [%date% %time%] ループに戻ります
echo %date% %time% ループに戻ります_by_mAgicTV(mtvGuidefail)_%batver% >> %tllogpath%
goto jobloop

rem sub_2######
:mtvGuidefail
echo [%date% %time%] mtvGuideから応答がありません
echo %date% %time% mtvGuideから応答がありません_by_mAgicTV(mtvGuidefail)_%batver% >> %tllogpath%
C:\mAgicTV\MemClCmd.exe
echo [%date% %time%] メモリーの掃除屋さんを使ってみました
echo %date% %time% メモリーの掃除屋さんを使ってみました(mtvGuidefail)_%batver% >> %tllogpath%
ping localhost -n 30 > nul
tasklist /v /fo "Table" /nh /fi "imagename eq mtvGuide.exe" | find /i "Not Responding" > nul
if %errorlevel%==0 goto mtvGuideNotResponse
goto mtvGuidesafe
:mtvGuideNotResponse
echo [%date% %time%] やはりmtvGuideが応答していません
echo %date% %time% やはりmtvGuideが応答していません_by_mAgicTV(mtvGuidefail)_%batver% >> %tllogpath%
echo [%date% %time%] 手動でメモリーリークとアプリフリーズを解決してください
echo %date% %time% キー待ち_by_mAgicTV(mtvGuidefail)_%batver% >> %tllogpath%
pause
echo [%date% %time%] ループに戻ります
echo %date% %time% ループに戻ります_by_mAgicTV(mtvGuidefail)_%batver% >> %tllogpath%
goto jobloop

rem sub_3######
:livefail
echo [%date% %time%] live異常を検出しました
echo %date% %time% LiveLog異常検出_by_mAgicTV(livefail)_%batver% >> %tllogpath%
echo [%date% %time%] mtvLogを切り離します
echo %date% %time% mtvLogを切り離します_by_mAgicTV(livefail)_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%livefail.txt" > nul
type nul > %mlogpath%
C:\mAgicTV\MemClCmd.exe
echo [%date% %time%] メモリーの掃除屋さんを使ってみました
echo %date% %time% メモリーの掃除屋さんを使ってみました(livefail)_%batver% >> %tllogpath%
echo [%date% %time%] ループに戻ります
echo %date% %time% ループに戻ります_by_mAgicTV(livefail)_%batver% >> %tllogpath%
goto jobloop

書込番号:19875108

ナイスクチコミ!0


スレ主 ボズシさん
クチコミ投稿数:276件

2016/05/14 19:59(1年以上前)

rem sub_4######
:mtvtaskerr
echo [%date% %time%] mtvtask異常を検出しました
echo %date% %time% mtvtask異常検出_by_mAgicTV(mtvtaskerr)_%batver% >> %tllogpath%
echo [%date% %time%] mtvLogを切り離します
echo %date% %time% mtvLogを切り離します_by_mAgicTV(mtvtaskerr)_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%mtvtaskerr.txt" > nul
type nul > %mlogpath%
C:\mAgicTV\MemClCmd.exe
echo [%date% %time%] メモリーの掃除屋さんを使ってみました
echo %date% %time% メモリーの掃除屋さんを使ってみました(mtvtaskerr)_%batver% >> %tllogpath%
echo [%date% %time%] ループに戻ります
echo %date% %time% ループに戻ります_by_mAgicTV(mtvtaskerr)_%batver% >> %tllogpath%
goto test2_rtn

rem sub_5######
:mtvtaskfail
echo [%date% %time%] mtvtask異常を検出しました
echo %date% %time% mtvtask異常検出_by_mAgicTV(mtvtaskfail)_%batver% >> %tllogpath%
echo [%date% %time%] mtvLogを切り離します
echo %date% %time% mtvLogを切り離します_by_mAgicTV(mtvtaskfail)_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%mtvtaskfail.txt" > nul
type nul > %mlogpath%
C:\mAgicTV\MemClCmd.exe
echo [%date% %time%] OSをリブートします
echo %date% %time% OSをリブートします_by_mAgicTV(mtvtaskfail)_%batver% >> %tllogpath%
goto osreboot

rem sub_6######
:osreboot
echo [%date% %time%] これまでのmtvlog.txtをshutdown.txtへ移行します
echo %date% %time% これまでのmtvlog.txtをshutdown.txtへ移行します(osreboot)_%batver% >> %tllogpath%
copy %mlogpath% "%mlogpath:~0,-4%_%time:~0,2%%time:~3,2%%time:~6,2%shutdown.txt" > nul
type nul > %mlogpath%
echo [%date% %time%] いざWindows再起動,一旦さようなら!
echo %date% %time% いざWindows再起動,一旦さようなら!_by_mAgicTV(osreboot)_%batver% >> %tllogpath%
shutdown -r
exit

==================================
3分割になってしまいました。
プロセス管理が mAgicマネージャ GTを終了できませんでした・・・とのメッセージが出た場合には深刻なエラーなのでOSリブートします。

書込番号:19875124

ナイスクチコミ!0


スレ主 ボズシさん
クチコミ投稿数:276件

2016/05/14 20:05(1年以上前)

次に\iodbadのディレクトリー自動消去bat最新版
============
@echo off
setlocal
set tllogpath=TL_Log%date:~0,4%%date:~5,2%%date:~8,2%.txt
set batver=ver214

cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
echo %date%_%time%_taskkill実行しましす_byDelliodbad_bat_%batver% >> %tllogpath%

rem ========= ウォッチドッグbat強制終了 =========
echo ウォッチドッグbat強制終了
taskkill /f /fi "windowtitle eq 管理者: mTgicTVmanagerウォッチドッグbat" >> %tllogpath%
ping localhost -n 62 > nul

rem ========= mtvGuide.exe強制終了 =========
echo mtvGuide.exe強制終了
taskkill /f /im mtvGuide.exe >> %tllogpath%
ping localhost -n 3 > nul

rem ========= mtvManager.exe強制終了 =========
echo mtvManager.exe強制終了
taskkill /f /im mtvMaintainer.exe
taskkill /f /im mtvSystemControl64.exe
taskkill /f /im mtvSystemControl86.exe
taskkill /f /im mtvUpdate.exe
taskkill /f /im mtvManager.exe
ping localhost -n 45 > nul

rem ========= iodbadフォルダー消去 =========
echo iodbadフォルダー消去
cd %APPDATA%"\I-O DATA\mAgicTV"
RD /s /q %APPDATA%"\I-O DATA\mAgicTV\iodbad
cd %APPDATA%"\I-O DATA\mAgicTV\TVManager"
echo %date%_%time%_iodbad_folder消去しました_byDelliodbad_bat_%batver% >> %tllogpath%
ping localhost -n 2 > nul

rem ========= Windows再起動 =========
echo %date%_%time%_Windowsを再起動します_byDelliodbad_bat_%batver% >> %tllogpath%
shutdown -r

書込番号:19875134

ナイスクチコミ!0


クチコミ一覧を見る


この製品の最安価格を見る

GV-MVP/XS3W
IODATA

GV-MVP/XS3W

ショップが販売価格を掲載するまでお待ちください 発売日:2012年10月下旬

GV-MVP/XS3Wをお気に入り製品に追加する <159

のユーザーが価格変動や値下がり通知、クチコミ・レビュー通知、購入メモ等を利用中です

クチコミ掲示板検索



検索対象カテゴリ
を対象として
選び方ガイド

最適な製品選びをサポート!

[PC用テレビチューナー]

PC用テレビチューナーの選び方ガイド

新着ピックアップリスト

ピックアップリストトップ

qoo10

新製品ニュース Headline

更新日:7月3日

クチコミ掲示板ランキング

(パソコン)

ユーザー満足度ランキング