『DS-Liteプチ切断検出バッチファイル』のクチコミ掲示板

[ボズシ]

DS-Liteが1分程度切断することがあり，Youtubeなどの動画閲覧をしていないと気づかないことがあるので，
nslookupコマンドでIPv6およびIPv4を監視するバッチを作ってみました。
稼働中のWindows10上で動作します。
まずアラーム音源(wavファイル)を2つ用意してください。
TTClockなどのFreeWareに同梱のピンポーンとかウィーウィーとか鳴るやつです。
そのwavファイルを任意のフォルダーにコピーします。
wavファイル名にスペースがあるとエラーになりますので，あればスペースを削除します。
下記ソースをメモ帳に貼り付けファイル名をInternetDet.batにリネームし任意のフォルダーにANIS形式で保存します。
次に12・13行目にコピー先の2つのwavファイルをフルパスで書き保存します。
私はBB.excite光Fitなので8行目のDSliteGateAddにgw.transix.jpを指定していますが，
楽天ひかりなどクロスパスならdgw.xpass.jpに書き換え編集してください。
このバッチを再起動時に自動的に走らせたい場合には下記フォルダーにショートカットを作製します。
C:\Users\All Users\Microsoft\Windows\Start Menu\Programs\StartUp
============================================
@echo off
if not "%1" == "1" (
start /min cmd /c call "%~f0" 1
exit
)
set batver=Ver101
set batname=InternetDet
set DSliteGateAdd=gw.transix.jp
set IPv4Add=yahoo.co.jp
set IPv4_flag=0
set IPv6_flag=0
set IPv4_wav_pass=C:\mAgicTV\Ding02.wav
set IPv6_wav_pass=C:\mAgicTV\WHOOP.WAV
:test
nslookup %IPv4Add% 8.8.8.8 | find /i "名前: %IPv4Add%" > nul
if %errorlevel%==1 (
set IPv4_flag=1
) else (
set IPv4_flag=0
)
cls
nslookup %DSliteGateAdd% | find /i "名前: %DSliteGateAdd%" > nul
if %errorlevel%==1 (
set IPv6_flag=1
) else (
set IPv6_flag=0
)
cls
if %IPv4_flag%==1 (
echo IPv4サイト_%IPv4Add%_への応答がありません
powershell -c (New-Object Media.SoundPlayer "%IPv4_wav_pass%"^).PlaySync^(^);
powershell -c (New-Object Media.SoundPlayer "%IPv4_wav_pass%"^).PlaySync^(^);
) else (
echo IPv4サイト_%IPv4Add%_応答あり
)
if %IPv6_flag%==1 (
echo IPv6サイト_%DSliteGateAdd%_への応答がありません
powershell -c (New-Object Media.SoundPlayer "%IPv6_wav_pass%"^).PlaySync^(^);
powershell -c (New-Object Media.SoundPlayer "%IPv6_wav_pass%"^).PlaySync^(^);
) else (
echo IPv6サイト_%DSliteGateAdd%_応答あり
)
echo %time% waiting 3sec
choice /T 3 /D y > nul
mode con: cols=48 lines=8 > nul
cls
goto test

書込番号：24057302

[ボズシ]

現在下から4，5行目の
echo %time% waiting 3sec
choice /T 3 /D y > nul
を
echo %time% waiting 58sec
choice /T 58 /D y > nul
と58秒毎の巡回に修正しております。

理由はBB.excite光Fit従量制であり，3秒毎のチェックではUP,DOWN含め普段の1.5倍程度ギガ消費となり，月当たり200GBを越えそうだった為です。

書込番号：24088833