『バッチファイルによる記録ファイルの自動圧縮』のクチコミ掲示板

[ボズシ]

防犯カメラとしてNASに録画データーを残す場合のファイルサイズの圧縮を自動で出来る様にバッチファイルを作成しました。
下記URLよりフリーのffmpegをダウンロードしこれを使います。
https://ffmpeg.zeranoe.com/builds/
尚CPUのリソースを大量消費し発熱しブザー鳴りますので「 -threads 2」とし2コアで走らせます。2コアの場合は「-threads 1」
カメラの数は4台，格納パスはS:\Lan_Cam\Data\Record\Camera x，実行ファイル格納庫はC:\Program Files\ffmpeg
以下バッチのソース

rem ==== 変数セット ====
set RecDrv=S:\
set Cam1path=Lan_Cam\Data\Record\Camera 1
set Cam2path=Lan_Cam\Data\Record\Camera 2
set Cam3path=Lan_Cam\Data\Record\Camera 3
set Cam4path=Lan_Cam\Data\Record\Camera 4
set ffmpeg_logpath=mp4ConvLog_%date:~0,4%-%date:~5,2%-%date:~8,2%.txt
rem ==== タイトル表示 ====
title ".avi→.mp4自動変換AutoMp4Conv.bat"
rem =====ここよりCam1の変換実行=====
pushd %RecDrv%..
cd %Cam1path%
call :Conv_ffmpeg
rem =====ここよりCam2の変換実行=====
pushd %RecDrv%..
cd %Cam2path%
call :Conv_ffmpeg
rem =====ここよりCam3の変換実行=====
pushd %RecDrv%..
cd %Cam3path%
call :Conv_ffmpeg
rem =====ここよりCam4の変換実行=====
pushd %RecDrv%..
cd %Cam4path%
call :Conv_ffmpeg
rem ===== end ====
cls
echo "変換終了"
exit
rem ==== 拡張子.aviファイルを抜き出しConv_ffmpeg_Subに引数として渡す =====
:Conv_ffmpeg
echo [%date% %time%] −−変換開始−− >> %ffmpeg_logpath%
for %%i in ("Schedule_"*.avi) do (
call :Conv_ffmpeg_Sub %%i
)
echo [%date% %time%] −−変換終了−− >> %ffmpeg_logpath%
exit /b
rem ==== avi形式を264mp4に変換し生成に成功したら元のaviファイルを消去 ====
:Conv_ffmpeg_Sub
echo Y | "C:\Program Files\ffmpeg\ffmpeg" -i %1 -threads 2 -r 3 -pix_fmt yuv420p -vcodec libx264 "%~n1.mp4"
cls
dir /b "%~n1.mp4"
if %errorlevel%==0 (
del "%1"
echo [%date% %time%] %1 to %~n1.mp4 >> %ffmpeg_logpath%
) else (
echo [%date% %time%] %1 >> %ffmpeg_logpath%
)
exit /b

書込番号：19875255