『M.2が認識するが初期化できない。』のクチコミ掲示板

[ひろしっくす。]

環境
CPU Ryzen 7 3700X
Graphic: ZOTAC GeForce RTX2060
MEM: 16GB x 2

現在2.5インチSSDをさして稼働させています。
そろそろM.2に移行しようと思い、さしたところマザーボードとOSどちらとも認識はしますが初期化できず使えない状況です。
以前の使っていたASUS TUF B450M-PLUS GAMINGですと問題なくできたのですが原因がわかりません。

ご教授お願い致します

書込番号：25281987

[揚げないかつパン]

初期化出来ないとは、パーティションを削除してから領域が確保出来ない？フォーマット出来ない？どっちだろう？
フォーマットできないのかな？
SATA繋いでる時に、サブで繋いでも初期化出来なかったんですか？

書込番号：25282004　スマートフォンサイトからの書き込み

[きとうくん]

＞マザーボードとOSどちらとも認識はしますが初期化できず
USBメモリにWindowsでもLinuxでもいいのでブート可能なデータを書き込んだものを用意して
電源落として、2.5インチSSDを外して
https://go.microsoft.com/fwlink/p/?LinkId=616447

M.2 SSD（SATAなのかNVMeなのか不明ですが）をCPU直結のスロット　M2A（M2A_CPU）に差し込んで
https://download.gigabyte.com/FileList/Manual/mb_manual_b550m-aorus-pro-p_j_1001.pdf?v=67f80f8bcb9d035a7df425f1ac35d070

USBメモリからブートしてください
認識されますよね？

書込番号：25282122

[魔境天使_Lucifer]

FYI

diskpart の clean で初期化すれば？

diskpart
https://learn.microsoft.com/ja-jp/windows-server/administration/windows-commands/diskpart

clean
https://learn.microsoft.com/ja-jp/windows-server/administration/windows-commands/clean

完全データ消去で廃棄ディスクからの情報漏えいを防ぐ（Windows diskpart編）
https://atmarkit.itmedia.co.jp/ait/articles/1004/16/news101.html

又は


UEFI/GPT ベースのハード ドライブ パーティション
https://learn.microsoft.com/ja-jp/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions?view=windows-11

サンプルのスクリプト
https://learn.microsoft.com/ja-jp/windows-hardware/manufacture/desktop/oem-deployment-of-windows-desktop-editions-sample-scripts?preserve-view=true&view=windows-10

----------------------------------------------------------------------------------------------------

rem == CreatePartitions-UEFI.txt ==
rem == These commands are used with DiskPart to
rem create four partitions
rem for a UEFI/GPT-based PC.
rem Adjust the partition sizes to fill the drive
rem as necessary. ==
select disk 0
clean
convert gpt
rem == 1. System partition =========================
create partition efi size=100
rem ** NOTE: For Advanced Format 4Kn drives,
rem change this value to size = 260 **
format quick fs=fat32 label="System"
assign letter="S"
rem == 2. Microsoft Reserved (MSR) partition =======
create partition msr size=16
rem == 3. Windows partition ========================
rem == a. Create the Windows partition ==========
create partition primary
rem == b. Create space for the recovery tools ===
rem ** Update this size to match the size of
rem the recovery tools (winre.wim)
rem plus some free space.
shrink minimum=2048
rem == c. Prepare the Windows partition =========
format quick fs=ntfs label="Windows"
assign letter="W"
rem === 4. Recovery partition ======================
create partition primary
format quick fs=ntfs label="Recovery"
assign letter="R"
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
list volume
exit


＊ 回復パーティション を 2GB にして有る。

書込番号：25282176

[uPD70116]

先ず使っているM.2 SSDと使っているスロットの情報を出しましょう。

「初期化できない」というのも、どうやって初期化しようとしていてどの様な状態になるのかを書かないと通じません。

書込番号：25284282